ACC SHELL

/**
 * File:
 *   inst_disk.ycp
 *
 * Module:
 *   Configuration of disk
 *   - schedular for partitioning lvm and raid modules
 *
 * Summary:
 *   Main file
 *
 * Authors:
 *   Michael Hager <mike@suse.de>
 *
 * $Id: inst_disk.ycp 49839 2008-08-07 18:23:07Z aschnell $
 *
 * Main file for disk configuration. Uses all other files.
 *
 */
{
    textdomain "storage";


    import "Wizard";
    import "Mode";
    import "Storage";
    import "StorageClients";


    y2milestone("start inst_disk");

    y2milestone( "PartMode %1 ProposalActive %2 ", Storage::GetPartMode(),
                 Storage::GetPartProposalActive() );


    if( !Storage::GetCustomDisplay() && Storage::GetPartMode() != "CUSTOM" &&
	Storage::GetPartMode() != "PROP_MODIFY" )
    {
	symbol ret = Storage::GetExitKey();
	y2milestone("end inst_disk ret:%1", ret);
	return ret;
    }


    if (!Storage::CheckBackupState("disk"))
	Storage::CreateTargetBackup("disk");


    boolean handle_dialog = Mode::normal() || Mode::repair();


    if (handle_dialog)
    {
	Wizard::CreateDialog();
	Wizard::SetDesktopIcon("disk");
	StorageClients::EnablePopup();
    }

    /*************************************************/
    /*   Let's do the work ...                       */
    /*************************************************/
    symbol ret = (symbol) WFM::CallFunction("inst_custom_part", [true, true]);

    if (handle_dialog)
    {
	Wizard::CloseDialog();
    }
    else
    {
	if( ret == `back || ret == `abort )
	{
	    Storage::RestoreTargetBackup("disk");
	}
	else if( ret == `next )
	{
	    Storage::DisposeTargetBackup("disk");
	    Storage::SetPartProposalActive(false);
	}
    }

    Storage::SaveExitKey(ret);
    y2milestone("end inst_disk ret:%1", ret);
    return ret;
}