ACC SHELL

/**
 * Copyright 2004, Novell, Inc.  All rights reserved.
 *
 * File:	firewall/wizards.ycp
 * Package:	Firewall configuration
 * Summary:	Wizards definition
 * Authors:	Lukas Ocilka <locilka@suse.cz>
 *
 * $Id: wizards.ycp 49128 2008-07-15 16:39:03Z locilka $
 */

{
    import "Wizard";
    import "Sequencer";
    import "Label";

    include "firewall/complex.ycp";
    include "firewall/dialogs.ycp";
    include "firewall/uifunctions.ycp";

    /**
     * Main workflow of the firewall configuration
     *
     * @return any returned value from Sequencer::Run() call
     */
    define any MainSequence() {
	map aliases = $[
	    "configuration" : ``(RunFirewallDialogs()),
	];

	map sequence = $[
	    "ws_start" : "configuration",
	    "configuration" : $[
		`abort	: `abort,
		`next	: `next,
	    ],
	];

	return Sequencer::Run(aliases, sequence);
    }

    /**
     * Whole configuration of firewall
     *
     * @return any returned value from Sequencer::Run() call
     */
    define any FirewallSequence() {
	map aliases = $[
	    "read"  	: [ ``( ReadDialog() ), true ],
	    "main"  	:   ``( MainSequence() ),
	    "summary"	:   ``( BoxSummaryDialog() ),
	    "write" 	: [ ``( WriteDialog() ), true ]
	];

	map sequence = $[
	    "ws_start" : "read",
	    "read" : $[
		`abort      : `abort,
		`next       : "main"
	    ],
	    "main" : $[
		`abort      : `abort,
		`next       : "summary"
	    ],
	    "summary" : $[
		`abort      : `abort,
		`next       : "write"
	    ],
	    "write" : $[
		`abort      : `abort,
		`next       : `next
	    ],
	];

	Wizard::CreateDialog();
	Wizard::SetAbortButton (`abort, Label::CancelButton());
	SetFirewallIcon();

	any ret = Sequencer::Run(aliases, sequence);

	UI::CloseDialog();
	return ret;
    }

    /**
     * Whole configuration of firewall
     *
     * @return any returned value from Sequencer::Run() call
     */
    define any FirewallAutoSequence() {
	map aliases = $[
	    "main"  	:   ``( MainSequence() ),
	    "summary"	:   ``( BoxSummaryDialog() ),
	];

	map sequence = $[
	    "ws_start" : "main",
	    "main" : $[
		`abort      : `abort,
		`next       : `next
	    ],
	];

	Wizard::CreateDialog();
	SetFirewallIcon();

	any ret = Sequencer::Run(aliases, sequence);

	UI::CloseDialog();
	return ret;
    }

    /**
     * Whole configuration of firewall
     *
     * @return any returned value from Sequencer::Run() call
     */
    define any FirewallInstallationSequence() {
	map aliases = $[
	    "main"  	:   ``( MainSequence() ),
	    "summary"	:   ``( BoxSummaryDialog() ),
	];

	map sequence = $[
	    "ws_start" : "main",
	    "main" : $[
		`abort      : `abort,
		`next       : `next
	    ],
	];

	Wizard::CreateDialog();
	SetFirewallIcon();

	any ret = Sequencer::Run(aliases, sequence);

	UI::CloseDialog();
	return ret;
    }

/* EOF */
}